@echo off
rem Matin — Word плагинін орнату (Windows, Word 2016 және жаңасы).
rem Не істейді: matin.kz-тен плагиннің баптау файлын алып, %LOCALAPPDATA%\Matin ішіне сақтайды
rem және оны Word-қа тіркейді (тек осы пайдаланушыға, әкімші құқығы керек емес).
rem Жою: осы файлды "/remove" деп іске қосыңыз немесе matin.kz/word бетіндегі нұсқауды қараңыз.
chcp 65001 >nul
setlocal
set "DIR=%LOCALAPPDATA%\Matin"
set "FILE=%DIR%\matin-word.xml"
set "KEY=HKCU\Software\Microsoft\Office\16.0\WEF\Developer"
set "ID=6d719ad1-17e1-47f1-bb57-b1389f39fbe0"

if /i "%~1"=="/remove" (
  reg delete "%KEY%" /v "%ID%" /f >nul 2>&1
  del "%FILE%" >nul 2>&1
  echo Matin плагині Word-тан алынды. Word-ты қайта ашыңыз.
  pause
  exit /b 0
)

echo Matin плагині орнатылып жатыр...
if not exist "%DIR%" mkdir "%DIR%"

curl.exe -fsSL "https://matin.kz/word-addin/manifest.xml" -o "%FILE%" >nul 2>&1
if not exist "%FILE%" powershell -NoProfile -Command "Invoke-WebRequest -UseBasicParsing 'https://matin.kz/word-addin/manifest.xml' -OutFile '%FILE%'" >nul 2>&1
if not exist "%FILE%" (
  echo.
  echo Файлды жүктеу мүмкін болмады. Интернетті тексеріп, қайталап көріңіз.
  pause
  exit /b 1
)

reg add "%KEY%" /v "%ID%" /t REG_SZ /d "%FILE%" /f >nul
if errorlevel 1 (
  echo.
  echo Word-қа тіркеу мүмкін болмады. info@matin.kz-ке жазыңыз.
  pause
  exit /b 1
)

echo.
echo Дайын! Word ашық болса, жауып, қайта ашыңыз.
echo «Главная» (Home) бетінде Matin батырмасы пайда болады.
echo.
pause